/*****************************************************************************************************************

SAS file name: PROC_SORT_Options
File location: 
_________________________________________________________________________________________________________________

Purpose: To demonstrate three PROC SORT options every SAS programmer should know
Author: Peter Clemmensen
Creation Date: 18/02/2018

This program supports the example page "Three PROC SORT Options You Should Know" on SASnrd.com

*****************************************************************************************************************/

/* Example Data - About 1.5 GB */
data TestData;
   length string $500; 
   string="SASnrd";
   do i=1 to 3e6;
      x=rand('Integer', 1, 10);
      output;
   end;
run;

/* PROC CONTENTS Reveals that work.MyData takes up about 1.5 GM Disc Space */
proc contents data=TestData;run;

/* SORTSIZE Option */

/* Check SORTSIZE System Option */
proc options option=(memsize sortsize);
run;

/* SORTSIZE=1GB */
proc sort data=TestData sortsize=1G;
   by x;
run;

/* SORTSIZE=2GB (default for my SAS session) */
proc sort data=TestData sortsize=2G;
   by x;
run;

/* TAGSORT Option */
proc sort data=TestData tagsort;
   by i;
run;

proc sort data=TestData;
   by i;
run;

/* PRESORTED Option */
proc sort data=TestData presorted;
   by i;
run;