/*****************************************************************************************************************

SAS file name: sasfile_statement
File location: 
_________________________________________________________________________________________________________________

Purpose: To demonstrate how to use the SASFILE Statement to load an entire SAS data set into memory.
Author: Peter Clemmensen
Creation Date: 01/01/2019

This program supports the example page "Load SAS Data Set Into Memory With SASFILE Statement" on SASnrd.com

*****************************************************************************************************************/

/* Example data */
data test;
   do x=1 to 10e6;
      output;
   end;
run;

/* Read data set 1000x1000=1Mio times without SASFILE Statement */
data Resample;
   do Sample=1 to 1000;
      do i=1 to 1000;
         point=rand('integer', 1, nobs);
         set test point=point nobs=nobs;
         output;
      end;
   end;
   stop;
run;

/* Load data set into memory first */
sasfile test load;
data Resample;
   do Sample=1 to 1000;
      do i=1 to 1000;
         point=rand('integer', 1, nobs);
         set test point=point nobs=nobs;
         output;
      end;
   end;
   stop;
run;
sasfile test close;