/*****************************************************************************************************************
 
SAS file name: proc_fcmp_location.sas
File location: 
__________________________________________________________________________________________________________________
 
Purpose: To demonstrate where and how PROC FCMP user defined functions are stored in SAS.
Author: Peter Clemmensen
Creation Date: 18/10/2019
 
This program supports the blog post "How Are PROC FCMP Functions Stored in SAS?" on SASnrd.com

*****************************************************************************************************************/

/* The Outlib Option */
proc fcmp outlib=work.fun.fun;
    function test();
        return(100);
    endsub;
quit;

proc fcmp outlib=work.fun.fun;
    function test2();
        return(200);
    endsub;
quit;

/* Options CMPLIB */
proc fcmp outlib=work.fun1.fun;
    function MyFunc();
        return (1);
    endsub;
quit;

proc fcmp outlib=work.fun2.fun;
    function MyFunc();
        return (2);
    endsub;
quit;

options cmplib=(work.fun2 work.fun1);

data test;
    a=MyFunc();
run;

/* Two Level Function calls */
proc fcmp outlib=work.f.f1;
    function test();
        return(1);
    endsub;
quit;

proc fcmp outlib=work.f.f2;
    function test();
        return(2);
    endsub;
quit;

options cmplib=work.f;

proc fcmp;
    a=f1.test();
    b=f2.test();
    put a= / b=;
quit;