/*****************************************************************************************************************
 
SAS file name: proc_datasets.sas
File location: 
__________________________________________________________________________________________________________________
 
Purpose: To provide a simple template for using Proc Datasets in SAS
Author: Peter Clemmensen
Creation Date: 20/08/2020
 
This program supports the example page "A Few Proc Datasets Examples in SAS"
 
*****************************************************************************************************************/

/* Copy sashelp.class from sashelp to work*/
proc datasets nolist;
   copy in=sashelp out=work memtype=data;
   select class;
run;quit;

/* Print content of class data set */
proc datasets lib=work;
   contents data=class;
run;quit;

/* Rename SAS data set */
proc datasets lib=work;
   change class=classdata;
run;

/* Modify formats and labels */
proc datasets lib=work nolist;
   modify classdata;
      format height 8.2;
      label name="Name";
run;

/* Create SAS index */
proc datasets lib=work nolist;
   modify classdata;
      index delete _all_;
      index create name / nomiss;
run;quit;

/* Delete SAS data set */
proc datasets library=work nolist;
   delete classdata;
quit;

/* Delete all data sets in WORK library */
proc datasets library=work kill nolist;
quit;